10 REM   AREA CODE FINDER
15 REM         BY
20 REM     MIKE COOKE
25 REM
30 REM
35 REM
40 REM
50 REM
55 POKE53280,0:POKE53281,0
56 PRINTCHR$(8)CHR$(14)
60 PRINT"[147][152]                                      [146]"
63 PRINT" [146]                                     [146]"
64 PRINT" [146]          [158][193]REA [195]ODE [198]INDER[152]           [146]"
65 PRINT" [146]                                     [146]"
66 PRINT"                                      [146]"
69 GOTO100
70 REM  *** CLEAR SPACE ***
73 PRINT"":FORT=1TO18:PRINT"                                       ":NEXT
74 PRINT"":RETURN
75 REM  *** PRESS A KEY ***
76 PRINT"[150]       PRESS <[211][208][193][195][197]>[150] TO CONTINUE"
77 GETSP$:IFSP$=""THEN77
78 IFSP$<>" "THEN77
79 RETURN
80 REM  *** INPUT ROUTINE ***
81 POKE204,0:CN=0:II$="":I$=""
82 CN=CN+1
83 GETI$:IFI$=""THEN83
84 IF I$="[140]" THEN 455
85 IFI$=CHR$(13)THENPRINT" ";:POKE204,1:RETURN
87 IFI$=CHR$(20)ANDCN>1THENCN=CN-2:II$=LEFT$(II$,CN):PRINTCHR$(20);:I$="":GOTO82
88 IF CN=26 THEN 83
89 IFI$<>" "ANDI$<"0"ORI$>"Z"THEN83
92 IFCN=1AND I$<>" "THENPRINTCHR$(ASC(I$)+32);:GOTO95
93 IFRIGHT$(II$,1)=" "AND I$<>" "THENPRINTCHR$(ASC(I$)+32);:GOTO95
94 PRINTI$;
95 II$=II$+I$:I$="":GOTO82
100 REM  *** INSTRUCTIONS ***
101 PRINT"[154]        [215]RITTEN BY [205]IKE [195]OOKE"
102 PRINT"         (C) [195]OPYRIGHT 1987"
103 PRINT" [208]UBLISHED BY [211]OFTDISK [208]UBLISHING, [201]NC."
105 PRINT"   [159][196]O YOU WANT INSTRUCTIONS? (Y/N)? ";
110 GETYN$:IFYN$=""THEN110
115 IFYN$="N"THEN200
116 IFYN$<>"Y"THEN110
117 GOSUB70
118 PRINT"[152]     [212]HIS PROGRAM'S PURPOSE IS TO GIVE"
119 PRINT"YOU THE AREA CODE FOR A CITY OR STATE."
120 PRINT"[212]O USE IT, SIMPLY CHOOSE THE AREA OF"
121 PRINT"[206]ORTH [193]MERICA THAT YOU NEED AND THEN"
122 PRINT"ENTER THE STATE/PROVINCE THAT YOU WANT"
123 PRINT"THE AREA CODE OF.  [201]N THOSE PLACES"
124 PRINT"THAT HAVE MORE THAN ONE CODE IN THEM,"
125 PRINT"YOU MUST ENTER THE NAME OF THE CITY"
126 PRINT"YOU WANT.  [201]T IS THEN COMPARED"
127 PRINT"WITH THE DATA ON THE DISK FOR THAT"
128 PRINT"STATE/PROVINCE.  [201]N LATER ISSUES OF"
129 PRINT"[213]P[212]IME, THERE WILL BE BONUS FILES THAT"
130 PRINT"CAN BE USED WITH THIS PROGRAM BUT THAT"
131 PRINT"HAVE MANY[152] MORE CITIES FOR EACH STATE."
132 GOSUB75:GOSUB70
133 PRINT"     [152][201]NSTEAD OF ENTERING THE FULL NAME"
134 PRINT"OF A STATE OR PROVINCE, YOU MAY ENTER"
135 PRINT"THEIR POSTAL CODE. [198]OR EXAMPLE, INSTEAD"
136 PRINT"OF TYPING [211][193][211][203][193][212][195][200][197][215][193][206], YOU MAY ENTER"
137 PRINT"[211][203].  [207]NE NOTE ABOUT [206]EW [217]ORK [195]ITY, IT"
138 PRINT"ISN'T IN FILE--YOU MUST ENTER THE NAME"
139 PRINT"OF THE ISLAND YOU WANT, SUCH AS, [194]RONX"
140 PRINT"[194]ROOKLYN, [205]ANHATTAN, [209]UEENS, OR [211]TATEN"
141 PRINT"[201]S."
150 GOSUB75:GOSUB70:GOTO100
200 REM *** MENU ***
205 GOSUB70:PRINT"[155]              [205]AIN [205]ENU":PRINT:PRINT
207 PRINTTAB(10)"[155]1)  [152][213]NITED [211]TATES/[195]ANADA":PRINT
209 PRINTTAB(10)"[155]2)  [152][195]ARIBBEAN [201]SLANDS":PRINT
211 PRINTTAB(10)"[155]3)  [152][205]EXICO":PRINT
212 PRINTTAB(10)"[155]4)  [152][213]P[212]IME [204]AND":PRINT:PRINT
215 PRINTTAB(14)"[155][217]OUR CHOICE? ";
217 GETYN$:IFYN$=""THEN217
218 IFVAL(YN$)<1ORVAL(YN$)>4THEN217
219 PRINTYN$
220 ONVAL(YN$)GOTO250,350,400,450
250 REM *** US OR CANADA ***
255 GOSUB70:PRINT"[155]          [213]NITED [211]TATES/[195]ANADA":PRINT:PRINT
256 PRINT"[151]       [208]RESS <[210][197][212][213][210][206]> FOR [205]AIN [205]ENU":PRINT
257 S$="":PRINT"[152]       [211]TATE: ";:GOSUB80:S$=II$:PRINT:PRINT:IFS$=""THEN200
259 PRINT"       [211]EARCHING...";
262 OPEN15,8,15:OPEN1,8,2,"STATES,S,R":INPUT#15,A,B$
265 IFA<20THEN269
266 PRINT"[196][201][211][203][160][197][210][210][207][210]!!!":PRINT:PRINTTAB(10)"[152][208]LEASE CHECK DRIVE"
267 PRINTTAB(10)"AND CORRECT ERROR.":GOSUB75:CLOSE1:CLOSE15:GOTO250
269 INPUT#1,A$:A$=""
270 FORT=1TO60:INPUT#1,A$:IFLEFT$(A$,2)=S$ORMID$(A$,4,(LEN(A$)-7))=S$THEN275
271 NEXTT:PRINT"[211]TATE NOT FOUND":CLOSE1:CLOSE15:GOSUB75:GOTO250
275 CLOSE1:CLOSE15:PRINT"[198]OUND ";:PRINT"[152]";CHR$(ASC(MID$(A$,4,1))+32);
276 FORT=5TO(LEN(A$)-4):IFMID$(A$,T-1,1)=" "THENPRINTCHR$(ASC(MID$(A$,T,1))+32);
277 IFMID$(A$,T-1,1)<>" "THENPRINTMID$(A$,T,1);
278 NEXTT:PRINT:PRINT
279 IFVAL(RIGHT$(A$,3))=0THEN285
280 PRINTTAB(7)"[193]LL POINTS: [150]";RIGHT$(A$,3):GOSUB75:GOTO250
285 PRINT"       [152][212]HIS STATE REQUIRES A CITY"
286 PRINT"       NAME.  [215]ILL YOU BE USING"
287 PRINT"       AN [155][207]RIGINAL[152] OR [155][194]ONUS[152] FILE?"
288 PRINT"       (O/B)? ";
289 GETYN$:IFYN$=""THEN289
290 IFYN$="O"THENPRINT"[155][207]RIGINAL.":GOTO300
291 IFYN$<>"B"THEN289
292 PRINT"[155][194]ONUS.":FORT=1TO500:NEXT:PRINT"[145][145][145][145][145]"
293 FORT=1TO4:PRINT"                                       ":NEXT:PRINT"[145][145][145][145][145][145]"
296 PRINT:PRINT"       [201]NSERT DISK WITH [194]ONUS FILE.":GOSUB75
297 PRINT"[145][145][145][145]"
298 FORT=1TO3:PRINT"                                       ":NEXT:PRINT"[145][145][145][145]"
299 GOTO310
300 FORT=1TO500:NEXT:PRINT"[145][145][145][145][145]"
302 FORT=1TO4:PRINT"                                       ":NEXT:PRINT"[145][145][145][145][145]"
310 PRINT"       [152][195]ITY:                    [157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][157]";:GOSUB80
311 C$=II$:IFC$=""THEN200
312 PRINT:PRINT:PRINT"       [211]EARCHING...";
314 OPEN15,8,15:OPEN1,8,2,LEFT$(A$,2)+",S,R":INPUT#15,A,B$:IFA<20THEN320
315 PRINT"[196][201][211][203] [197][210][210][207][210]!!!":PRINTTAB(10)"[152]PLEASE CHECK DRIVE":CLOSE1:CLOSE15
316 PRINTTAB(10)"AND CORRECT ERROR.":GOSUB75
317 PRINT"[145][145][145][145][145][145][145]":FORT=1TO6:PRINT"                                       "
318 NEXTT:PRINT"[145][145][145][145][145][145][145][145]":GOTO310
320 INPUT#1,CT:FORT=1TOCT:INPUT#1,A$:IFC$=LEFT$(A$,(LEN(C$)))THEN324
321 NEXTT:PRINT"[195]ITY NOT FOUND":CLOSE1:CLOSE15:GOSUB75:IFYN$="B"THEN331
322 GOTO250
324 CLOSE1:CLOSE15:PRINT"[198]OUND ";:PRINT"[152]";CHR$(ASC(MID$(A$,1,1))+32);
325 FORT=2TO(LEN(A$)-4):IFMID$(A$,T-1,1)=" "THENPRINTCHR$(ASC(MID$(A$,T,1))+32);
326 IFMID$(A$,T-1,1)<>" "THENPRINTMID$(A$,T,1);
327 NEXTT:PRINT:PRINT
329 PRINT"[152]       [193]REA CODE IS: [150]";RIGHT$(A$,3)
330 GOSUB75:IFYN$="O"THENGOTO250
331 GOSUB70:PRINT"[155]     [210]E-INSERT ORIGINAL PROGRAM DISK.":GOSUB75:GOTO250
350 REM *** CARIBBEAN IS. ***
355 GOSUB70:PRINT"[155]            [195]ARIBBEAN [201]S.":PRINT:PRINT:PRINT
360 PRINT"[152]          [208]UERTO [210]ICO: [150]809":PRINT
365 PRINT"[152]          [214]IRGIN [201]S.:  [150]809":PRINT:PRINT
370 GOSUB75:GOTO200
400 REM *** MEXICO ***
405 GOSUB70:PRINT"[155]              [205]EXICO":PRINT:PRINT:PRINT
410 PRINT"[152]       [205]EXICO [195]ITY:      [150]905"
415 PRINT:PRINT"[152]       [193]LL OTHER POINTS: [150]706":PRINT:PRINT
420 GOSUB75:GOTO200
450 REM *** UPTIME LAND ***
455 POKE204,1:SYS(8*4096)+4